home *** CD-ROM | disk | FTP | other *** search
/ Software Vault: The Gold Collection / Software Vault - The Gold Collection (American Databankers) (1993).ISO / cdr18 / mrun210.zip / MRUN210E.WAS < prev    next >
Text File  |  1993-04-28  |  20KB  |  763 lines
  1. ;MailRun v2.10:  Part E, addulfile
  2. ;1992-1993 Gerald P. Sully, all rights reserved.
  3.  
  4. #comment
  5. **************************************************************************
  6. **************************************************************************
  7. * 
  8. * This file contains routines related to adding a "Upload File"
  9. * item to a mailrun.  It puts up the Upload Files dialog box,
  10. * which displays the contents of the available files index (the
  11. * *.udx file for the mailrun).  When a file is selected from the 
  12. * list, a detailed description is displayed from the *.ubf file 
  13. * for the mailrun).
  14. * 
  15. **************************************************************************
  16. **************************************************************************
  17. #endcomment
  18.  
  19. #define MRUN210E
  20. #define MRUN210DE
  21.  
  22. #include "mrun210.h"
  23.  
  24. string DXFileTabs, OldUDX, OldUBF, MRunUDX, MRunUBF, LastChoice
  25. string UploadDir, DownloadDir
  26. integer InULDir, ULSortField
  27.  
  28. #comment
  29. *********************************************************************
  30. * 
  31. * MAIN()
  32. * 
  33. * Calls checkchild(), updateudx(), interfaceon(), getnewdesc(),
  34. * getbbsi(), getitemi(), getulfiles(), checkchanged(), 
  35. * getbbscoord(), getitemcoord(), gettaskstring(),
  36. * makebbslist(), ulfilebox(), insertulfile(), delulfile(),
  37. * menudim(), makefullname(), sortidx(), checkfile(),
  38. * clearfiledesc()
  39. * 
  40. * Adds a SendFile item to the mailrun.  An feditbox is
  41. * used to display the file description in order to take
  42. * advantage of wordwrap.  The flistbox displays the
  43. * contents of MAILRUN.UDX, which contains information on
  44. * any file downloaded by MailRun, plus additional files
  45. * found in the upload directory.  A file description must
  46. * be at least 6 characters, but may be as long as needed.
  47. * 
  48. *********************************************************************
  49. #endcomment
  50.  
  51. proc main
  52. string LastUDX, LastUBF, FullFileName, temp
  53. integer dialogstatus
  54. integer i, j, InUDX
  55.     menudim()
  56.     checkchild()
  57.     findfirst MailRun
  58.     MailRunTrunc = $FILENAME
  59.     DXFileTabs = "58,92,130,305,315,319,322,325,328"
  60.     profilerd MailRun "MailRun" "UploadDir" UploadDir
  61.     profilerd MailRun "MailRun" "DownloadDir" DownloadDir
  62.     profilerd MailRun "MailRun" "ULSortField" ULSortField
  63.     i = getbbsi()
  64.     j = getitemi()
  65.     FileDesc = makefullname(TempDir, "DESC.TMP")
  66.     OldUDX = makefullname(TempDir, "OLDUDX.TMP")
  67.     OldUBF = makefullname(TempDir, "OLDUBF.TMP")
  68.     LastUDX = makefullname(MailRunDir, "MAILRUN.UDX")
  69.     LastUBF = makefullname(MailRunDir, "MAILRUN.UBF")
  70.     MRunUDX = makefullname(TempDir, "MAILRUN.UDX")
  71.     MRunUBF = makefullname(TempDir, "MAILRUN.UBF")
  72.     if isfile FileDesc
  73.         delfile FileDesc
  74.     endif
  75.     if isfile MRunUDX
  76.         delfile MRunUDX
  77.     endif
  78.     if isfile MRunUBF
  79.         delfile MRunUBF
  80.     endif
  81.     copyfile LastUDX MRunUDX
  82.     copyfile LastUBF MRunUBF
  83.     if not (checkfile(MRunUDX) && checkfile(MRUNUBF))
  84.         getulfiles()
  85.     endif
  86.     LastChoice = ""
  87.     FLAGS &= UNCHANGED
  88.     interfaceon()
  89.     makebbslist()
  90.     ulfilebox()
  91.     dialogstatus = $DIALOG
  92.     while dialogstatus != 1
  93.         switch dialogstatus
  94.             case 10
  95.                 ;User selected "Add"
  96.                 insertulfile(&j)
  97.                 TaskItem = gettaskstring(i, j)
  98.             endcase
  99.             case 11
  100.                 ;User selected "Save"
  101.                 if FLAGS & CHANGED
  102.                     updateudx()
  103.                     FLAGS &= UNCHANGED
  104.                     updatedlg -1
  105.                 endif
  106.             endcase
  107.             case 12
  108.                 ;User selected "Delete"
  109.                 delulfile()
  110.             endcase
  111.             case 13
  112.                 ;User selected "Refresh"
  113.                 statmsg "Refreshing Uploads List from Upload Directory..."
  114.                 getulfiles()
  115.                 updatedlg -1
  116.                 statmsg ""
  117.             endcase
  118.             case 50
  119.                 ;User selected a sort radiobutton
  120.                 profilewr MailRun "MailRun" "ULSortField" ULSortField
  121.                 sortidx(MRunUDX, ULSortField)
  122.                 updatedlg 16
  123.             endcase
  124.             case 130
  125.                 ;User selected a file from the listbox
  126.                 if checkchanged()
  127.                     getnewdesc()
  128.                     updatedlg 137
  129.                 else
  130.                     FileChoice = LastChoice
  131.                     updatedlg 16
  132.                 endif
  133.             endcase
  134.             case 170
  135.                 ;User changed BBSs with the combobox
  136.                 i = getbbscoord()
  137.                 j = getitemcoord()
  138.                 TaskItem = gettaskstring(i, 0)
  139.             endcase
  140.             case 230
  141.                 ;User entered a name in the File Name box
  142.                 FullFileName = makefullname(UploadDir, FileName)
  143.                 if isfile FullFileName
  144.                     InULDir = 1
  145.                 else
  146.                     InULDir = 0
  147.                 endif
  148.                 interfaceoff()
  149.                 openfile(MRunUDXFile, MRunUDX, _READWRITE, _TEXT)
  150.                 InUDX = checkudx(FileName)
  151.                 if InUDX
  152.                     fseek MRunUDXFile -100 1
  153.                     fgets MRunUDXFile FileChoice
  154.                     fgets MRunUDXFile FileChoice
  155.                     strextract temp FileChoice "`t" 0
  156.                     while not strcmpi temp FileName
  157.                         fgets MRunUDXFile FileChoice
  158.                         strextract temp FileChoice "`t" 0
  159.                     endwhile
  160.                 endif
  161.                 fclose MRunUDXFile
  162.                 interfaceon()
  163.                 if InUDX
  164.                     makedesc(MRunUBF)
  165.                 else                
  166.                     clearfiledesc()
  167.                 endif
  168.                 updatedlg -1
  169.             endcase
  170.             case 250
  171.                 ;User entered a file description
  172.                 if !(FLAGS & CHANGED)
  173.                     FLAGS |= CHANGED
  174.                 endif
  175.             endcase
  176.         endswitch
  177.         dialogstatus = $DIALOG
  178.     endwhile
  179.     delfile LastUDX
  180.     delfile LastUBF
  181.     copyfile MRunUDX LastUDX
  182.     copyfile MRunUBF LastUBF
  183. endproc
  184.  
  185.  
  186. #comment
  187. *********************************************************************
  188. * 
  189. * INSERTULFILE()
  190. * 
  191. * Called by main()
  192. * 
  193. * Calls checkperm(), openfile(), updateudx(), insertitem(),
  194. * interfaceon(), interfaceoff(), makefullname(), checkudx(),
  195. * clearfiledesc(), shortdesc()
  196. * 
  197. * Adds a SendFile item to the *.MRN file and the task list.
  198. * 
  199. *********************************************************************
  200. #endcomment
  201.  
  202. proc insertulfile
  203. intparm j
  204. string ULDescString, ULFileString, FullFileName
  205. string ULFileSpec, Perm
  206. string StatString, CopyboxMsg
  207. integer ULDescLength
  208. integer Response, InUDX
  209.     interfaceoff()
  210.     if NULLSTR FileName
  211.         ;User hasn't selected a file
  212.         usermsg "You must select a file first."
  213.         return
  214.     endif
  215.     if InULDir == 0
  216.         strupr FileName
  217.         strfmt CopyBoxMsg \
  218.             "%s is not in the Upload Directory.`r`nCopy it now?" \
  219.             FileName
  220.         strlwr FileName
  221.         sdlgmsgbox "MailRun Message" CopyBoxMsg QUESTION \
  222.             OKCANCEL Response 1
  223.         switch Response
  224.             case 1
  225.                 ;User selected "OK"
  226.                 ULFileSpec = makefullname(DownloadDir, FileName)
  227.                 dir ULFileSpec FullFileName
  228.                 if NULLSTR FullFileName
  229.                     return
  230.                 endif
  231.                 if not isfile FullFileName
  232.                     sdlgmsgbox "MailRun Message" "No such file!" \
  233.                         EXCLAMATION OK Response 1
  234.                     return
  235.                 endif
  236.                 copyfile FullFileName UploadDir
  237.                 if not strcmpi ULFileSpec FullFileName
  238.                     ;if the user chose a file other than the one specified
  239.                     ;get the name of the file
  240.                     findfirst FullFileName
  241.                     FileName = $FILENAME
  242.                     strlwr FileName
  243.                     ;determine whether it is already in the uploads database
  244.                     openfile(MRunUDXFile, MRunUDX, _READWRITE, _TEXT)
  245.                     InUDX = checkudx(FileName)
  246.                     fclose MRunUDXFile
  247.                     if InUDX == 0
  248.                         ;if it isn't in the uploads database, put it there
  249.                         clearfiledesc()
  250.                         FLAGS |= CHANGED
  251.                         updateudx()
  252.                     endif
  253.                 endif
  254.                 InULDir = 1
  255.                 updatedlg -1
  256.             endcase
  257.             case 2
  258.                 ;User selected "Cancel"
  259.                 return
  260.             endcase
  261.         endswitch
  262.     endif
  263.     ;No description may be less than 30 characters
  264.     openfile(FileDescFile, FileDesc, _READWRITE, _NORMAL)
  265.     fread FileDescFile ULDescString 65 ULDescLength
  266.     fclose FileDescFile
  267.     if ULDescLength < 6
  268.         usermsg "Please enter a longer description."
  269.     elseif shortdesc(ULDescString, ULDescLength)
  270.         ;If everything is OK...
  271.         if FLAGS & CHANGED
  272.             ;Add the new description to the database
  273.             updateudx()
  274.             FLAGS &= UNCHANGED
  275.             updatedlg 16
  276.         endif
  277.         Perm = checkperm()
  278.         strupr FileName
  279.         strfmt ULFileString \
  280.             "1,%s,SendFile,%s,%s" Perm FileName Conf
  281.         strfmt StatString \
  282.             "Added to %s:  `"Upload %s to Conference %s`"" \
  283.             BBS FileName Conf
  284.         j++
  285.         insertitem(j, ULFileString)
  286.         strlwr FileName
  287.         statmsg StatString
  288.     endif
  289.     interfaceon()
  290. endproc
  291.  
  292.  
  293. #comment
  294. *********************************************************************
  295. * 
  296. * SHORTDESC()
  297. * 
  298. * Called by insertulfile()
  299. * 
  300. * Calls findstring()
  301. * 
  302. * If the current BBS type is WildCat! or RBBS, limits the 
  303. * upload description length to 60 or 45 characters,
  304. * respectively.  Gives user an opportunity to enter a new 
  305. * description if the current one is too long.
  306. * 
  307. *********************************************************************
  308. #endcomment
  309.  
  310. func shortdesc : integer
  311. strparm ULDescString
  312. intparm ULDescLength
  313. string ULMsg, TypeName
  314. integer Response, MaxLength
  315.     profilerd MailRun BBS "BBSType" BBSType
  316.     if (findstring(BBSType, "WildCat") && (ULDescLength > 60)) || \
  317.         (findstring(BBSType, "RBBS") && (ULDescLength > 45))
  318.         if findstring(BBSType, "WildCat")
  319.             substr ULDescString ULDescString 0 60
  320.             MaxLength = 60
  321.             TypeName = "WildCat!"
  322.         else
  323.             substr ULDescString UlDescString 0 45
  324.             MaxLength = 45
  325.             TypeName = "RBBS"
  326.         endif
  327.         strfmt ULMsg "A %s file description has a maximum length \
  328. of %d characters.  The description for %s will be truncated to read:\
  329. `r`n`r`n%s`r`n`r`nDo you wish to continue?" \
  330.             TypeName MaxLength FileName ULDescString
  331.         sdlgmsgbox "MailRun Message" ULMsg QUESTION YESNO Response 2
  332.         switch Response
  333.             case 6
  334.                 return 1
  335.             endcase
  336.             case 7
  337.                 return 0
  338.             endcase
  339.         endswitch
  340.     else
  341.         return 1
  342.     endif
  343. endfunc
  344.  
  345.  
  346. #comment
  347. *********************************************************************
  348. * 
  349. * DELULFILE()
  350. * 
  351. * Called by main()
  352. * 
  353. * Calls killfile(), makefullname()
  354. * 
  355. * Deletes a file from the upload database index.
  356. * 
  357. *********************************************************************
  358. #endcomment
  359.  
  360. proc delulfile
  361. string DelBoxMsg, FullFileName
  362. integer Response
  363.     if not NULLSTR FileName
  364.         if InULDir == 1
  365.             ;If the selected file is in the upload directory
  366.             strfmt DelBoxMsg "Delete file %s as well?" FileName
  367.             sdlgmsgbox "MailRun Message" DelBoxMsg QUESTION \
  368.                 YESNOCANCEL Response 1
  369.             switch Response
  370.                 case 2
  371.                     ;User selected "Cancel"
  372.                     return
  373.                 endcase
  374.                 case 6
  375.                     ;User selected "Yes"
  376.                     FullFileName = makefullname(UploadDir, FileName)
  377.                     delfile FullFileName
  378.                 case 7
  379.                     ;User selected "No"
  380.                     killfile()
  381.                 endcase
  382.             endswitch
  383.         else
  384.             killfile()
  385.         endif
  386.         FLAGS &= UNCHANGED
  387.         updatedlg -1
  388.     endif
  389. endproc
  390.  
  391.  
  392. #comment
  393. *********************************************************************
  394. * 
  395. * KILLFILE()
  396. * 
  397. * Called by delulfile()
  398. * 
  399. * Calls openfile(), clearfiledesc(), getnewdesc()
  400. * 
  401. * Deletes a file from the upload database index.
  402. * 
  403. *********************************************************************
  404. #endcomment
  405.  
  406. proc killfile
  407. string UDXString, UDXFile, temp
  408.     ;Copy all but the new description to the new UDX file
  409.     copyfile MRunUDX OldUDX
  410.     openfile(OldUDXFile, OldUDX, _READWRITE, _TEXT)
  411.     openfile(MRunUDXFile, MRunUDX, _CREATE, _TEXT)
  412.     fgets OldUDXFile UDXString
  413.     while not feof OldUDXFile
  414.         ;Read lines until the end of file or the current file
  415.         strextract UDXFile UDXString "`t" 0
  416.         if strcmpi UDXFile FileName
  417.             exitwhile
  418.         endif
  419.         fputs MRunUDXFile UDXString
  420.         fgets OldUDXFile UDXString
  421.     endwhile
  422.     fgets OldUDXFile UDXString
  423.     ;get the new listbox selection
  424.     FileChoice = UDXString
  425.     while not feof OldUDXFile
  426.         fputs MRunUDXFile UDXString
  427.         fgets OldUDXFile UDXString
  428.     endwhile
  429.     if NULLSTR FileChoice
  430.         ;if the deleted line was the last in the file
  431.         ;back up one line and read it
  432.         fseek MRunUDXFile -100 2
  433.         fgets MRunUDXFile temp
  434.         while not NULLSTR temp
  435.             FileChoice = temp
  436.             fgets MRunUDXFile temp
  437.         endwhile
  438.     endif
  439.     if not NULLSTR FileChoice
  440.         getnewdesc()
  441.     else
  442.         FileName = ""
  443.         clearfiledesc()
  444.     endif
  445.     fclose OldUDXFile
  446.     fclose MRunUDXFile
  447.     delfile OldUDX
  448. endproc
  449.  
  450.  
  451. #comment
  452. *********************************************************************
  453. * 
  454. * GETNEWDESC()
  455. * 
  456. * Called by main(), killfile()
  457. * 
  458. * Calls makedesc(), makefullname()
  459. * 
  460. * Gets the file name and description from the index entry
  461. * and determines whether the file is in the upload directory.
  462. * 
  463. *********************************************************************
  464. #endcomment
  465.  
  466. proc getnewdesc
  467. string FullFileName
  468.     LastChoice = FileChoice
  469.     strextract FileName FileChoice "`t" 0
  470.     FullFileName = makefullname(UploadDir, FileName)
  471.     if isfile FullFileName
  472.         InULDir = 1
  473.     else
  474.         InULDir = 0
  475.     endif
  476.     makedesc(MRunUBF)
  477. endproc
  478.  
  479.  
  480. #comment
  481. *********************************************************************
  482. * 
  483. * GETULFILES()
  484. * 
  485. * Called by main()
  486. * 
  487. * Calls openfile(), checkudx(), checkfile(), sortidx(),
  488. * interfaceon(), interfaceoff(), makefullname()
  489. * 
  490. * Updates the Upload directory file description database.
  491. * 
  492. *********************************************************************
  493. #endcomment
  494.  
  495. proc getulfiles
  496. string FileSize, FileDate, FDesc, DescBegin, DescLength, UDXString
  497. string ULFileFull, ULFileTrunc, FullFileName
  498. long FS, DB, DL, NDB, counter
  499. integer char
  500. integer InUDX
  501.     interfaceoff()
  502.     if checkfile(MRunUDX) && checkfile(MRunUBF)
  503.         copyfile MRunUDX OldUDX
  504.         copyfile MRunUBF OldUBF
  505.         openfile(OldUDXFile, OldUDX, _READWRITE, _TEXT)
  506.         openfile(OldUBFFile, OldUBF, _READWRITE, _NORMAL)
  507.     else
  508.         openfile(OldUDXFile, OldUDX, _CREATE, _TEXT)
  509.         openfile(OldUBFFile, OldUBF, _CREATE, _NORMAL)
  510.     endif
  511.     openfile(MRunUDXFile, MRunUDX, _CREATE, _TEXT)
  512.     openfile(MRunUBFFile, MRunUBF, _CREATE, _NORMAL)
  513.     fgets OldUDXFile UDXString
  514.     while not feof OldUDXFile
  515.         ;loop through the old .UDX file
  516.         ;extract all fields
  517.         strextract ULFileTrunc UDXString "`t" 0
  518.         strextract FileSize UDXString "`t" 1
  519.         strextract FileDate UDXString "`t" 2
  520.         strextract FDesc UDXString "`t" 3
  521.         strextract DescBegin UDXString "`t" 4
  522.         strextract DescLength UDXString "`t" 5
  523.         atol DescBegin DB
  524.         atol DescLength DL
  525.         ftell MRunUBFFile NDB
  526.         ;go to the beginning of the file description
  527.         fseek OldUBFFile DB 0
  528.         ;copy the description to the new .UBF file
  529.         for counter = 1 upto DL
  530.             fgetc OldUBFFile char
  531.             fputc MRunUBFFile char
  532.         endfor
  533.         ;add the index line to the new .UDX file
  534.         fstrfmt MRunUDXFile "%s`t%s`t%s`t%s`t%ld`t%ld`r`n" \
  535.             ULFileTrunc FileSize FileDate FDesc NDB DL
  536.         fgets OldUDXFile UDXString
  537.     endwhile
  538.     ;Add any new files found in the uploads directory
  539.     FullFileName = makefullname(UploadDir, "*.*")
  540.     findfirst FullFileName
  541.     while FOUND
  542.         ;Loop through all files in the upload directory
  543.         ULFileTrunc = $FILENAME
  544.         InUDX = checkudx(ULFileTrunc)
  545.         if InUDX == 0
  546.             ULFileFull = makefullname(UploadDir, ULFileTrunc)
  547.             getfsize ULFileFull FS
  548.             getfdate ULFileFull FileDate
  549.             strlwr ULFileTrunc
  550.             fseek MRunUDXFile 0 2
  551.             fstrfmt MRunUDXFile "%s`t%ld`t%s`t`t0`t0`r`n" \
  552.                 ULFileTrunc FS FileDate
  553.         endif
  554.         findnext
  555.     endwhile
  556.     fclose MRunUDXFile
  557.     fclose MRunUBFFile
  558.     fclose OldUDXFile
  559.     fclose OldUBFFile
  560.     delfile OldUDX
  561.     delfile OldUBF
  562.     interfaceon()
  563.     sortidx(MRunUDX, ULSortField)
  564. endproc
  565.  
  566.  
  567. #comment
  568. *********************************************************************
  569. * 
  570. * CHECKUDX()
  571. * 
  572. * Called by insertulfile(), getulfiles()
  573. * 
  574. * Checks whether a given file is already in the UDX List.
  575. * If it is, a value of 1 is returned, if not, the file
  576. * is added to the list and a value of 0 is returned.
  577. * 
  578. *********************************************************************
  579. #endcomment
  580.  
  581. func checkudx : integer
  582. strparm CkFileName
  583. string UDXFile, UDXFileString
  584. integer InUDX
  585.     rewind MRunUDXFile
  586.     InUDX = 0
  587.     fgets MRunUDXFile UDXFileString
  588.     while not feof MRunUDXFile
  589.         strextract UDXFile UDXFileString "`t" 0
  590.         if strcmpi CkFileName UDXFile
  591.             InUDX = 1
  592.             exitwhile
  593.         endif
  594.         fgets MRunUDXFile UDXFileString
  595.     endwhile
  596.     return InUDX
  597. endfunc
  598.  
  599.  
  600. #comment
  601. *********************************************************************
  602. * 
  603. * UPDATEUDX()
  604. * 
  605. * Called by main(), insertulfile()
  606. * 
  607. * Calls openfile(), interfaceon(), interfaceoff(),
  608. * makefullname(), sortidx()
  609. * 
  610. * Updates the Upload directory file description database
  611. * and index files.
  612. * 
  613. *********************************************************************
  614. #endcomment
  615.  
  616. proc updateudx
  617. string FileDate, FileSize, FullFileName
  618. string ULDescString, UDXString, UDXFile
  619. long DescBegin, DescLength, l
  620. integer ULDescLength
  621. integer char
  622.     interfaceoff()
  623.     ;Copy all but the new description to the new UDX file
  624.     copyfile MRunUDX OldUDX
  625.     openfile(OldUDXFile, OldUDX, _READWRITE, _TEXT)
  626.     openfile(MRunUDXFile, MRunUDX, _CREATE, _TEXT)
  627.     fgets OldUDXFile UDXString
  628.     while not feof OldUDXFile
  629.         ;Read lines until the end of file or the current file
  630.         strextract UDXFile UDXString "`t" 0
  631.         if strcmpi UDXFile FileName
  632.             exitwhile
  633.         endif
  634.         fputs MRunUDXFile UDXString
  635.         fgets OldUDXFile UDXString
  636.     endwhile
  637.     ;Get the size and date
  638.     if NULLSTR UDXString
  639.         FullFileName = makefullname(UploadDir, FileName)
  640.         if isfile FullFileName
  641.             getfsize FullFileName l
  642.             ltoa l FileSize
  643.             getfdate FullFileName FileDate
  644.             InULDir = 1
  645.         else
  646.             FileSize = "???"
  647.             FileDate = "??/??/??"
  648.             InULDir = 0
  649.         endif
  650.     else
  651.         strextract FileSize UDXString "`t" 1
  652.         strextract FileDate UDXString "`t" 2
  653.     endif
  654.     ;Discard the old description line
  655.     fgets OldUDXFile UDXString
  656.     FileChoice = UDXString
  657.     while not feof OldUDXFile
  658.         fputs MRunUDXFile UDXString
  659.         fgets OldUDXFile UDXString
  660.     endwhile
  661.     openfile(MRunUBFFile, MRunUBF, _READWRITE, _NORMAL)
  662.     ;go to the end of the description database
  663.     fseek MRunUBFFile 0 2
  664.     ftell MRunUBFFile DescBegin
  665.     DescLength = 0
  666.     ULDescLength = 0
  667.     ULDescString = ""
  668.     
  669.     ;read characters from the description box into the database
  670.     openfile(FileDescFile, FileDesc, _READWRITE, _NORMAL)
  671.     fgetc FileDescFile char
  672.     while not feof FileDescFile
  673.         ;read characters until all have been read
  674.         if ((char >= 0x20) && (char <= 0x7E)) || \
  675.             ((char >= 0xA0) && (char <= 0xFE))
  676.             ;Ignore non-printing characters
  677.             fputc MRunUBFFile char
  678.             if ULDescLength < 46
  679.                 ;No special characters in the index file either
  680.                 strfmt ULDescString "%s%c" ULDescString char
  681.                 ULDescLength++
  682.             endif
  683.             DescLength++
  684.         endif
  685.         fgetc FileDescFile char
  686.     endwhile
  687.     fclose MRunUBFFile
  688.     fclose FileDescFile
  689.     
  690.     ;Strip partial words from end of description
  691.     if ULDescLength == 46
  692.         ULDescLength--
  693.         strpeek ULDescString ULDescLength char
  694.         while char > 32
  695.             strdelete ULDescString ULDescLength 1
  696.             ULDescLength--
  697.             strpeek ULDescString ULDescLength char
  698.         endwhile
  699.     endif
  700.     
  701.     strfmt FileChoice "%s`t%s`t%s`t%s`t%ld`t%ld" \
  702.         FileName FileSize FileDate ULDescString DescBegin DescLength
  703.     fputs MRunUDXFile FileChoice
  704.     fclose OldUDXFile
  705.     fclose MRunUDXFile
  706.     delfile OldUDX
  707.     sortidx(MRunUDX, ULSortField)
  708.     interfaceon()
  709. endproc
  710.  
  711.  
  712. #comment
  713. *********************************************************************
  714. * 
  715. * ULFILEBOX()
  716. * 
  717. * Called by main()
  718. * 
  719. * Draws the Upload Files Dialog Box.
  720. * 
  721. *********************************************************************
  722. #endcomment
  723.  
  724. proc ulfilebox
  725. PermRadio = 2
  726. Conf = "0"
  727. FileName = ""
  728. destroydlg
  729. HelpPage = 10
  730. dialogbox 19 38 324 201 15 "Upload Files" HELPID HelpPage
  731.    text  12 27 56 8 left "Filename"
  732.    text  70 27 40 8 left "Size"
  733.    text  104 27 34 8 left "Date"
  734.    text  142 27 117 8 left "Description"
  735.    flistbox 12 38 300 50 MRunUDX DXFileTabs single FileChoice
  736.    groupbox 12 89 300 17
  737.    radiobutton 26 94 60 11 "Unsorted" ULSortField
  738.    radiobutton 91 94 67 11 "Sort by Name" 
  739.    radiobutton 172 94 61 11 "Sort by Size" 
  740.    radiobutton 241 94 62 11 "Sort by Date" endgroup
  741.    text  13 112 49 8 left "Filename:"
  742.    editbox 12 122 101 12 FileName
  743.    text  129 112 67 8 left "Description:"
  744.    feditbox 129 122 182 50 FileDesc
  745.    text  14 158 78 8 right "U/L to Conference:"
  746.    editbox 96 156 16 12 Conf
  747.    radiobutton 12 178 53 13 "Permanent" PermRadio
  748.    radiobutton 70 178 54 13 "Temporary" endgroup
  749.    pushbutton 130 179 30 14 "&Add" normal default
  750.    pushbutton 168 179 30 14 "&Save" normal
  751.    pushbutton 206 179 30 14 "De&lete" normal
  752.    pushbutton 244 179 30 14 "&Refresh" normal
  753.    pushbutton 282 179 30 14 "&Done" cancel
  754.    text  76 9 80 8 right "Upload File to:"
  755.    combobox 160 7 70 42 BBSList BBS sort
  756.    checkbox 13 140 100 10 "File in uploads directory?" InULDir
  757. enddialog
  758. disable CTRL 70
  759. endproc
  760.  
  761.  
  762.  
  763.